upload of H.235v2 white contribution

Euchner Martin Martin.Euchner at MCHP.SIEMENS.DE
Fri Jun 30 06:34:23 EDT 2000


I propose to change the ABNF to the following:

      H323-URL      = "H323:" user [ "@" hostport ]
      user          = 1*( unreserved / escaped )
      hostport      = host [":" port]
      host          = hostname / IPv4address / IPv6reference
      hostname      = *( domainlabel "." ) toplabel [ "." ]
      domainlabel   = alphanum / alphanum *( alphanum / "-" ) alphanum
      toplabel      = ALPHA / ALPHA *( alphanum / "-" ) alphanum
      IPv6reference = "[" IPv6address "]"
      IPv6address   = hexpart [ ":" IPv4address ]
      IPv4address   = 1*3DIGIT "." 1*3DIGIT "." 1*3DIGIT "." 1*3DIGIT
      IPv6prefix    = hexpart "/" 1*2DIGIT
      hexpart       = hexseq | hexseq "::" [ hexseq ] | "::" [ hexseq ]
      hexseq        = hex4 *( ":" hex4)
      hex4          = 1*4HEXDIG
      port          = 1*DIGIT
      unreserved    = alphanum / mark
      alphanum      = ALPHA / DIGIT
      mark          = "-" / "_" / "." / "!" / "~" / "*" / "'"
                    / "(" / ")" / "&" / "=" / "+" / "$" / ","
      escaped       = "%" HEXDIG HEXDIG

This introduces IPv6 adresses according to RFCs 2732, 2373 and 2396. The
ABNF still relies on RFC 2234.

It also corrects the IPv4 address by limiting each segment to three
digits.

I am not too sure about the 'port'. Although 1*DIGIT makes absolutely
sense, most schemes currently in use are more relaxed about it and just
do a DIGIT.

I am also not too sure about the extended user definition and the
password extension which are used e.g. in SIP and HTTP:

      H323-URL      = "H323:" userinfo [ "@" hostport ]
      userinfo      = user [ ":" password ]
      user          = *( unreserved / escaped
                    / "&" / "=" / "+" / "$" / "," )
      password      = *( unreserved | escaped
                    / "&" / "=" / "+" / "$" / "," )
   etc.

Could we need that?

Cheers,

Michael
(welser at acm.org)

> -----Original Message-----
> From: Mailing list for parties associated with ITU-T Study Group 16
> [mailto:ITU-SG16 at mailbag.cps.intel.com]On Behalf Of Paul E. Jones
> Sent: Monday, June 26, 2000 12:23 PM
> To: ITU-SG16 at mailbag.cps.intel.com
> Subject: H.323 URL Text
>
>
> Folks,
>
> I have attached the text that I propose adding to the H.323v4 document
> relating to the H.323 URL scheme.  I think this text is weak,
> but I expect
> contributions to be brought to define the usage of this
> scheme-- presently,
> there really is no procedural text.
>
> I'd like to point out that I removed the telephone number
> portions of the
> URL, which should make both Orit and Bob happy :-)
>
> Please review the text and the ABNF grammar for errors.  You
> will note one
> small bit of procedural text near the end where it discusses
> the fact that a
> Gatekeeper may modify the alias provided to the Gatekeeper.
> The substance
> of that existed in TD-50 (Osaka) and I thought that it was
> important to go
> ahead and include that at the very least.
>
> Please, give me feedback.  Mr. Bowen and I plan to post H.323v4 and
> H.225.0v4 this week for review.  A formal announcement will
> be made later
> today or tomorrow.
>
> Best Regards,
> Paul
>

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
For help on this mail list, send "HELP ITU-SG16" in a message to
listserv at mailbag.intel.com



More information about the sg16-avd mailing list